Scoped Tuples for the Ambient (TOTAM)

TOTAM is tuple space model geared towards mobile ad hoc networks which provides a dynamic scoping mechanism that limits the transportation of tuples. TOTAM adopts features of both federated tuple spaces and replication-based approaches: it combines replication of tuples for read operations while guaranteeing atomicity for remove operations. In TOTAM, tuple spaces are annotated with tuple space descriptors used to determine the scope of a tuple. The novelty of our approach lies in the use of these tuple space descriptors to determine that a tuple should be propagated before it is transmitted. This enhances privacy and decreases the burden on the network traffic in a wide range of applications.

TOTA is one of the most dynamic tuple-based solutions for coordination in mobile networks. It relies on tuples which hop from location to location to coordinate distributed application nodes. Rather than merging local tuple spaces upon network connection as other tuple-based approaches like LIME, tuples themselves decide how to propagate from a tuple space to another. This means that tuples are injected in the network with and can autonomously propagate according to application-specific propagation rules expressed in the tuples themselves. These propagation rules are crucial to provide programmers with a flexible mechanism to achieve context-awareness based not only on connectivity but also on semantic information.

However, in TOTA tuples are sent to all communication partners in range. Upon arrival at the receiver side, the tuple itself decides whether it has to be stored in that tuple space. As all devices can potentially access all information, information cannot be hidden or scoped. By transmitting tuples potential malicious or non-intended users are provided with sensitive information. Not only does sending all tuples blindly to all communication partners in range may be unacceptable for certain applications, it also creates a network traffic overhead and has performance repercussions on mobile devices which are likely to have scarce resources, such as limited battery life.

TOTAM provides the programmer with means to scope the tuples themselves, i.e the tuples can dynamically adjust their scope as they hop from location to location. By means of tuple space descriptors, programmers can scope their tuples preventing them to be propagated to unwanted locations. This scope is determined before the tuple is transmitted, thus allowing the programmer to prevent the physical transportation of tuples to devices which are not targeted.

Figure above illustrates how a scoped tuple is propagated through the TOTAM network. It depicts two types of locations, the blue and red locations corresponding to two teams of a multi-player game scenario where users (blue team) can use their PDA’s to chase dangerous (virtual) gangsters (red team) in the outdoors. The scope of the propagated tuple has been limited to blue locations. Figure (a) illustrates that a tuple is injected from the location with a star. This location is connected to four blue locations and one red location. As the scope of the tuple is limited to blue locations the tuple is only sent to the four blue locations. From those four locations the tuple is transitively propagated obeying the scope of the tuple until all connected blue locations are reached without being transmitted to a red location. Note that one blue location is not transitively connected to the sending device and thus does not receive the tuple. Figure (b) illustrates that a blue location moved into the range of the isolated blue location and thus, transmits the tuple to it. Again the tuple is not transmitted to nearby red locations. It is important to note from this operational sketch that the first isolated location receives a tuple without being connected at any time with the start location in which the tuple was originally inserted.

TOTAM has been implemented in AmbientTalk. The system library shipped with AmbientTalk contains the TOTAM implementation under at/lang/totam.at.

In order to use TOTAM, you need to load the library and create a TOTAM tuple space as follows:

import /.at.lang.totam;
def myTupleSpace := makeTupleSpace();

A description can be passed in the makeTupleSpace operation in order to activate the scoping mechanism (as we will explain later).

To create a tuple or a template (i.e. a tuple with wildcards or “holes”), the 'tuple:' operation can be used as follows:

 
// a “hallo” message tuple from wolf.
def halloTuple := tuple: ["Message", “wolf”, “hallo”];
// a template for message tuples from wolf.
def wolfTuples := tuple: ["Message", “wolf”, var: `content];
// a template for any message tuples.
def msgTuples := tuple: ["Message", var: `from, var: `content];

TOTAM provides operations to add and read tuples from the tuple space as follows:

// add tuple to tuple space
myTupleSpace.out(halloTuple);
// get a Message tuple
def aMessageTuple := myTupleSpace.rdp(msgTuples);
// get all Message tuples.
def messageTuples := myTupleSpace.rdg(msgTuples);

The rdp(template) and rdg(template) operations return a tuple or all tuples matching the template in the tuple space if present (without removing), respectively. Note that if no tuple is present matching the template, nil is given back.

In the original Linda model, read and in operations were provided to return a copy of the tuple and remove the tuple from the tuple, respectively. Those operations where blocking. TOTAM, inspired by Lime, offers non-blocking variants of these operations:

def msgTuples := tuple: [Message, var: `from, var: `content];
myTupleSpace.whenever: msgTuples read:{
  system.println(“Got message: “ + content + “ from: ” + from);
};

myTupleSpace.whenever: wolfTuples in:{  
  system.println(“ “ + from + “ says: “ + content);
};

The whenever:read: operation takes as parameter a template and a block closure which is asynchronously applied each time a tuple matching the template is added to the tuple space. The whenever:in: operation works similarly but it also removes the tuple matching the template. Following Linda's in semantics, if several whenever:in: operations could be triggered for one tuple, only one of them will succeed. Variables specified in the template are bound in the body of the block closure to the concrete value of the tuple that matched the template. Both operations return a subscription object which understands a cancel message to stop the interest in tuples matching the template. Note also that both operations have a when: variant which only triggers once the block closure for the first tuple that matches the template.

The out(tuple) operation actually inserts a private tuple in the tuple space. In order for applications to insert a public tuple, thereby making it available to other collocated TOTAM systems, the inject: operation is provided.

myTupleSpace.goOnline(); 
myTupleSpace.inject: halloTuple;

Note that the network facilities are disabled by default, so before injecting something in the network, the goOnline() method must be called on the tuple space.

Similar to TOTA, public tuples are replicated and shared amongst devices when devices come into communication range. We thus say that tuple are propagated into the TOTAM network, i.e. a logical network formed by all devices which host a TOTAM tuple space. The spread of tuples into the TOTAM network can be controlled by means of a propagation protocol. Each tuple injected into the network carries a propagation protocol that can be customized by developers. What follows shows the default propagation protocol:

def defaultPropagationProtocol(){
  isolate: {
    //receiver-side protocol
    def decideEnter(ts) { true };
    def doAction(ts){};
    def changeTupleContent(ts){self};
    def decideStore(ts) {true};
    //sender-side protocol
    def inScope(senderDescriptor,receiverDescriptor){ true };
    def decideDie(ts){false};
  };
};

Custom propagation protocols can be created and attached to a tuple before being injected in the network as follows:

//define a new propagation protocol
def blueProtocol := propagationProtocol: {
  def inScope(senderDescriptor,receiverDescriptor) { 
    receiverDescriptor.team == "blue" };
};
// attach the protocol to a tuple
def aBlueTuple := tuple: ["Message", "hallo"] 
withPropagationProtocol: blueProtocol;
// inject the tuple to the network
def publication := inject: aBlueTuple;

The propagationProtocol: operation creates a propagation protocol object which extends the default propagation protocol object with other semantics. this sample code shows a protocol based on the operational sketch figure that checks whether the receiver of the tuple is part of the blue team. This is attached to the tuple by means of the tuple:withPropagationProtocol: operation which is then injected into the network. The inject: operation returns a publication object which understands two methods:

// cancels the propagation of the tuple to new devices in the TOTAM network.
publication.cancel();
// sends an antituple to notify the removal of this tuple in devices which carry a copy.
publication.retract();

Upon a cancel operation, TOTAM stops the injection of the tuple into newly discovered devices in the TOTAM network. Upon a retract operation, TOTAM injects in the TOTAM network an antituple for the removed tuple. For every tuple, there is (conceptually) a unique antituple with the same format and content, but with a different sign. All tuples injected by an application have a positive sign while their antituples have a negative sign. Whenever a tuple and its antituple are stored in the same tuple space, they immediately annihilate one another, i.e. they both get removed from the tuple space. By means of antituples, TOTAM can “unsend” tuples injected into the network.

TOTAM: Scoped Tuples for the Ambient, C. Scholliers, E. Gonzalez Boix, W. De Meuter. Proceedings of the Second International DisCoTec Workshop on Context-aware Adaptation Mechanisms for Pervasive and Ubiquitous Services (CAMPUS 2009), from Electronic Communications of the EASST, eds. 2009. ( pdf)