User Tools

Site Tools


Sidebar

Jump to
AmbientTalk
CRIME
iScheme

at:tutorial:objects

This is an old revision of the document!


In this section, we explain how the object-oriented programming paradigm is implemented in AmbientTalk.

Objects, fields and methods

In AmbientTalk, objects are not instantiated from classes. Rather, they are either created ex-nihilo or by cloning and adapting existing objects, in the spirit of prototype-based programming such as in the SELF programming language. The definition of a prototypical object contains a number of fields and methods that represent the object's state and behaviour respectively.

The following code illustrates the ex-nihilo creation of an object:

def Point := object: { 
  def x := 0;
  def y := 0;
  def init(aX,aY) {
    x := aX;
    y := aY;
  };
  def sumOfSquares() { x*x + y*y };
}

The above code defines an ex-nihilo created point object and binds it to the variable Point. The object itself does not carry a name (i.e. it is “anonymous”). Like all definitions in AmbientTalk, fields and methods are defined using the def keyword. Fields are defined using a def name := value syntax while methods are defined using a def name(parameters) {body} syntax.

In the example above, the state of the point object is composed of x and y fields while its behaviour corresponds to the init and sumOfSquares methods.

As already explained in the basic programming part of the tutorial, AmbientTalk not only supports traditional canonical syntax (e.g. o.m(a,b,c)) but also keyworded syntax (e.g. o.at: key put: value). Keyworded syntax can be used both for method definitions and for message sends.

For Smalltalk/Self programmers: note that a keyworded message send does require a message sending operator (like .) in between the receiver and the message, which is different from Smalltalk and Self. As will be described in later chapters, AmbientTalk features more than one message sending operator, so the programmer must explicitly specify which one to use.

Sending messages

In AmbientTalk, computation is expressed in terms of objects sending messages to one another. Messages are used to invoke the fields and methods of the objects.

> point.x
>>2
> point.sumOfSquares()
>>13

This code shows two messages sent to the point object defined above in this section. The x message acts as an accessor for the x field. The sumOfSquares message selects the sumOfSquares method and evaluates its body.

Cloning and instantiation

As said before in this section, AmbientTalk objects are created ex-nihilo or by cloning and adapting an existing object. The code below shows the instatiation of a new point object by using the cloning semantics.

> def anotherPoint := point.new(2,3)

Every object understands the message new, which creates a clone (a shallow copy) of the receiver object and initializes the clone by invoking its init method with the arguments that were passed to new (aX and aY in the example of the point object). Hence, the init method plays the role of “constructor” for AmbientTalk objects. AmbientTalk’s object instantiation protocol closely corresponds to class instantiation in class-based languages, except that the new object is a clone of an existing object, rather than an empty object allocated from a class.

AmbientTalk also provides a clone language contsruct which only creates a clone of the receiver object without calling the init method (as a matter of fact the new message desribed above does nothing more but invoking this construct and the init method subsequently).

> def clonedPoint := clone: point

Delegation and cloning

AmbientTalk features object inheritance or delegation. By means of delegation, an object can reuse and extend the defintion of another establishing a parent-child relationship. We identify two kinds of delegation relationships: IS-A and SHARE-A. These relationships define two different semantics for clonning child objects. Whereas clonning a IS-A child also clones its parent, SHARE-A child shares the parent of the cloned object (see the figure below).

:at:tutorial:isaversussharea.png

The following code shows how to extend objects with a IS-A relationship. It uses the extend: with: language construct.

> def point3D := extend: point with: {
    def z := 0;
    def sumOfSquares() {
      super^sumOfSquares() + z*z
    }
  }

The following code shows how to extend objects with a SHARE-A relationship. It uses the share: with: language construct.

> def point3D := share: point with: {
    def z := 0;
    def sumOfSquares() {
      super^sumOfSquares() + z*z
    }
  }

Delegation and dynamic inheritance

The parent of an object is bound to a field named super. The delegation chain defined by an object and its parent (or chain of parents) determines the scope in which the message is looked up. As any field in AmbientTalk objects, the super field can be dynamically modified.

> def openConnection := object: {...};
> def closedConnection := object: {...};
> def connection := object: {
    def open() {
      super := openConnection.new();
    };
    def close() {
      super := closedConnection.new();
    };
  }
In AmbientTalk, self and super indicate the current object and its parent respectively. While the former corresponds to a language keyword the latter is just a field name of the object.

First-class delegation

AmbientTalk provides an explicit delegation operator ^ (the “caret” or “hat” symbol). The code below illustrates the use of the ^ operator in the implementation of the init method of the point3D object.

> def point3D := extend: point with: {
    def z := 0;
    def init(aX, aY, aZ) {
      super^init(aX, aY);
      z := aZ;
    };
  }

A message sent to an object using the ^ symbol (e.g. to the parent object in the example above) will start the method lookup in this object (and its parents) and then execute the method body in the lexical scope of the message sender (self is bound to the message sender).

The delegation operator does not have the same semantics as the dot notation. A message sent to super using the dot notation will not only start the method lookup in the object bound the super field but also bind the self pseudo variable to this object.

Encapsulation

In AmbientTalk, all fields and methods are “public” via selection. Still, a field or method can be made “private” by means of lexical scoping. The following code shows the definition of an object inside the definition of a function. The fields and methods of this object cannot be accessed directly from outside the funuction.

> def makeObject(hidden) {
    object: {
      def foo() { /* use hidden */ }
    }
  }

Due to the encapsulation of this object the following instruction fails:

> makeObject(5).hidden;
>>Lookup failure : selector hidden could not be found in 
  <object:5068254>
at/tutorial/objects.1184007649.txt.gz · Last modified: 2007/07/09 21:03 (external edit)