User Tools

Site Tools


Sidebar

Jump to
AmbientTalk
CRIME
iScheme

at:tutorial:reflection

This is an old revision of the document!


Reflective Programming

Reflection is an integral part of the AmbientTalk programming language. Through the use of reflection, the core language can be extended with both programming support as well as new language constructs. Both examples require a different kind of reflective access. The introduction of programming support (e.g. to visualise AmbientTalk objects) relies on introspection, the ability for a program to inspect and reason about parts of its own state. This particular flavour of reflection is quite popular and is available in most contemporary programming languages. AmbientTalk goes beyond introspection and also allows objects to supply alternative semantics for the default meta-level operations. This particular form of reflection, called intercession, allows enriching AmbientTalk from within the language itself.

The reflective model of AmbientTalk is based on mirrors, meta-level objects which allow one to reflect on an objects state and behaviour. How to create such mirrors and how they can be used is demonstrated in the first part of the tutorial. The second part of the tutorial showcases how to construct mirages, objects which override the default meta-level operations with custom behaviour. This tutorial concludes with a brief overview of the meta-level operations which are offered by AmbientTalk mirrors.

Mirrors

As we have already mentioned in the introduction, AmbientTalk uses a mirror-based architecture to provide reflective access to its objects. The basic principle of a mirror-based architecture is that all reflective facilities are encapsulated in a mirror object which provides reflective access to precisely one object, its reflectee. Moreover, the mirror of the object is not directly accessible as a slot of the object. Instead, a separate factory must be used to create mirrors, which allows the program to hand out different mirrors according to the dynamic call chain, the requesting object etc. The factory can be used implicitly using the reflect: primitive. Once a mirror has been created, it can be used for instance to produce a listing of an object's methods, as is exemplified below.

>def mirrorOnOne := reflect: 1;
>><mirror on:1>
>mirrorOnOne.listMethods();
>>[<native method:==>, <native method:+>, 
   <native method:<=>>, <native method:to:do:>, ...]

The code excerpt presented above uses the mirror to introspect on a natively implemented object (the number 1) and uses the listMethods meta-method. The result is a table of the methods provided by this object, including the comparators == and , operations such as + and the enumeration construct to:do:. Since the number 1 is a natively implemented object, all of its methods are provided with builtin implementations. This can be witnessed from the example since all methods are denoted to be native methods.

When reflecting upon a user-defined object, we can observe that every object has some implictly defined methods and fields, in addition to those which are defined when constructing the object. Every AmbientTalk object has a super field as well as primitive implementations for the methods ==, new and init. The primitive methods play a somewhat peculiar role in an object since they are present in every object, yet they can be safely overridden without leading to a name clash (which normally occurs when one object attempts to define two methods with the same name).

>def inspectable := object: { 
 def map(arg1, @restArgs) { restArgs.map(arg1); } };
>><object:4927258>
>def mirrorOnInspectable := reflect: inspectable;
>><mirror on:<object:4927258>>
>mirrorOnInspectable.listFields()
>>[<field:super>]
>mirrorOnInspectable.listMethods()
>>[<method:map>, <primitive method:new>, 
   <primitive method:init>, <primitive method:==>]
>def method := mirrorOnInspectable.grabMethod(`map);
>><method:map>
>method.bodyExpression
>>restArgs.map(arg1)

Using a mirror on an object, it is possible to get access to a representation of the object's methods and fields, allowing the programmer to read the value of a field, or as is exemplified above inspect the body of a method. This type of reflection is quite useful to for instance construct an inspector for live AmbientTalk objects.

In addition to allowing a program to reason about the structure of its objects, mirrors can also be used to perform operations such as method invocation in a first-class manner. The following example shows how to select all zero-argument methods whose name starts with test and invoke them.

>def isTestMethod(meth) {
   (meth.name.text ~= "test.*").and:
   { meth.parameters == [] } };
>><closure:isTestMethod>
>def retainTestMethods(obj) {
   (reflect: obj).listMethods()
     .filter: &isTestMethod };
>><closure:retainTestMethods>
>def runTest(obj) {
   retainTestMethods(obj).each: { | meth | 
     (reflect: obj).invoke(obj, meth.name, []) } };
>><closure:runTest>
>runTest(object: {def testOne() { system.println(`ok) } });
ok
>>nil

This part of the tutorial has provided a basic feeling of how AmbientTalk's default mirrors can be created and the kind of power they offer. The default mirrors offer a much wider range of capabilities than those presented in this section, however. A complete overview of all meta-operations will be presented in the final chapter of this tutorial.

Mirages

Extending the AmbientTalk core language involves adding objects which have a different implementation for some of the default meta-operations. In this part of the tutorial, we describe how a programmer could define objects which allow for the dynamic addition of unknown methods and fields. First of all, we need to create a mirror instance which we can use to create new objects from. This can be performed using the mirror: language construct as follows.

def dynamicExtensionMirror := mirror: {
  def doesNotUnderstand(selector) {
    system.println("You selected a slot" + selector + "which does not exist in this object.");
    system.println("You can provide a definition here or press enter to report this error.");
    def input := system.readln();
    if: !( "" == input ) then: {
      def definition := read: input;
      eval: definition in: base;
    } else: {
      super^doesNotUnderstand(selector);
    };
  };
}
TODO Add a word on base

This mirror overrides the default implementation of the meta-operation doesNotUnderstand to report that a slot was selected which did not exist. The user is then provided with an opportunity to provide the missing definition or pass this opportunity in which case the default behaviour is executed (i.e. an error is being reported). The mirror defined above can be used subsequently to create objects with an adapted meta-object protocol. Such objects are called mirages as they are not ordinary objects, but rather objects whose appearance and behaviour are defined by a custom mirror. Mirages are constructed using a variation on the object: constructor as is illustrated below.

def mirage := object: {
  def m() { self.x };
} mirroredBy: dynamicExtensionMirror;

When invoking the method m on the mirage, doesNotUnderstand will be invoked with a selector `x, since the object does not have a slot with the request name. The user can mediate this oversight by typing def x := 5 at which point the slot will be added to the object. Using the code from the previous section, the user can verify that the mirage object now sports both an x and an x:= slot.

Note that the use of self.x in the above example is crucial as the doesNotUnderstand operation is not called when a lexical lookup fails.

Whereas the example provided above may seem a little contrived, the reflective capabilities of AmbientTalk allow it to be extended with many abstraction relating to distributed computing for mobile ad hoc networks (AmbientTalk's main domain of application). An example of a language construct which is conceived as a reflective extension to the language is for instance futures, which are discussed in the next chapter of this tutorial.

The Metaobject Protocol

The Meta-Object Protocol of AmbientTalk can be divided into a series of independent protocols. Whereas the full semantics and signature of the meta-methods can be found in the language reference, this section provides an overview of the various protocols.

The Message Passing Protocol consists of methods to deal with both synchronous and asynchronous message sending. It provides necessary hooks to intercept both the reception of asynchronous messages and the invocation of synchronous messages. Moreover, it provides a hook to intercept asynchronous messages being sent by the object, allowing the object to add additional metadata to the message. The invoke meta-method illustrated above is an example of a method belonging to this protocol.

The Object Passing Protocol consists of two methods pass and resolve, which allow an object to prescribe how it should be passed to other objects and how the object should subsequently be resolved upon arrival. The default semantics allow objects to be passed by copy if they are tagged with the Isolate type tag. Otherwise, objects are passed by handing out a far object reference.

The Slot Access and Modification Protocol consists of operations which allow trapping both dynamic access and modification to slots. For instance, o.x can be intercepted using the invokeField meta-method, while o.x := 5 is trapped using invoke where the selector will equal x:=.

The Structural Access Protocol consists of operations used list all available slots, get access to a first-class slot representation and to add new slots to an existing object. The listMethods and listFields meta-methods used in previous examples are elements of this protocol.

The Instantiation Protocol consists of the clone and newInstance methods, which are implictly called when using base-level code of the form clone: object and object.new(@args) respectively. In the default implementation, newInstance calls clone() to create a clone of the current object, and subsequently invokes the base-level init method with the supplied arguments on the cloned object.

The Relational Testing Protocol consists of the methods isCloneOf and isRelatedTo which allow testing whether 2 objects are related through cloning or a combination of cloning and object extension. Note that these operators are not able to discern that objects were generated by the same constructor function or (by extension) the execution of identical code in different actors.

The Type Testing Protocol consists of the methods isTaggedAs and getTypeTags, the former of which tests whether an object is transitively tagged with a particular type (i.e. this operation considers type tags of parent objects). getTypeTags on the other hand returns only the type tags which were explicitly attributed to this object (i.e. it does not return type tags attributed to the parent objects).

The Evaluation Protocol ensures that any AmbientTalk object can be part of a parse tree, and therefore every object provides meaningful implementations of the eval and quote meta-operations. The eval operation is called when evaluating a parsetree and typically returns the evaluated object itself, except for explicit parse-tree elements such as definition and method invocations.

at/tutorial/reflection.1193332158.txt.gz · Last modified: 2008/06/23 15:08 (external edit)