This is an old revision of the document!


Scoped Tuples for the Ambient (TOTAM)

TOTAM is tuple space model geared towards mobile ad hoc networks which provides a dynamic scoping mechanism that limits the transportation of tuples. TOTAM adopts features of both federated tuple spaces and replication-based approaches: it combines replication of tuples for read operations while guaranteeing atomicity for remove operations. In TOTAM, tuple spaces are annotated with tuple space descriptors used to determine the scope of a tuple. The novelty of our approach lies in the use of these tuple space descriptors to determine that a tuple should be propagated before it is transmitted. This enhances privacy and decreases the burden on the network traffic in a wide range of applications.

Motivation

TOTA is one of the most dynamic tuple-based solutions for coordination in mobile networks. It relies on tuples which hop from location to location to coordinate distributed application nodes. Rather than merging local tuple spaces upon network connection as other tuple-based approaches like LIME, tuples themselves decide how to propagate from a tuple space to another. This means that tuples are injected in the network with and can autonomously propagate according to application-specific propagation rules expressed in the tuples themselves. These propagation rules are crucial to provide programmers with a flexible mechanism to achieve context-awareness based not only on connectivity but also on semantic information.

However, in TOTA tuples are sent to all communication partners in range. Upon arrival at the receiver side, the tuple itself decides whether it has to be stored in that tuple space. As all devices can potentially access all information, information cannot be hidden or scoped. By transmitting tuples potential malicious or non-intended users are provided with sensitive information. Not only does sending all tuples blindly to all communication partners in range may be unacceptable for certain applications, it also creates a network traffic overhead and has performance repercussions on mobile devices which are likely to have scarce resources, such as limited battery life.

Scoped Tuples for the Ambient

TOTAM provides the programmer with means to scope the tuples themselves, i.e the tuples can dynamically adjust their scope as they hop from location to location. By means of tuple space descriptors, programmers can scope their tuples preventing them to be propagated to unwanted locations. This scope is determined before the tuple is transmitted, thus allowing the programmer to prevent the physical transportation of tuples to devices which are not targeted.

:research:totamspace.jpg

Figure above illustrates how a scoped tuple is propagated through the TOTAM network. It depicts two types of locations, the blue and red locations corresponding to two teams of a multi-player game scenario where users (blue team) can use their PDA’s to chase dangerous (virtual) gangsters (red team) in the outdoors. The scope of the propagated tuple has been limited to blue locations. Figure (a) illustrates that a tuple is injected from the location with a star. This location is connected to four blue locations and one red location. As the scope of the tuple is limited to blue locations the tuple is only sent to the four blue locations. From those four locations the tuple is transitively propagated obeying the scope of the tuple until all connected blue locations are reached without being transmitted to a red location. Note that one blue location is not transitively connected to the sending device and thus does not receive the tuple. Figure (b) illustrates that a blue location moved into the range of the isolated blue location and thus, transmits the tuple to it. Again the tuple is not transmitted to nearby red locations. It is important to note from this operational sketch that the first isolated location receives a tuple without being connected at any time with the start location in which the tuple was originally inserted.

API

TOTAM has been implemented in AmbientTalk. The system library shipped with AmbientTalk contains the TOTAM implementation under at/lang/totam.at.

In order to use TOTAM, you need to load the library and create a TOTAM tuple space as follows:

import /.at.lang.totam;
def myTupleSpace := makeTupleSpace();

A description can be passed in the makeTupleSpace operation in order to activate the scoping mechanism (as we will explain later). To create a tuple or a template, the tuple operation can be used as follows:

 
// a “hallo” message tuple from wolf.
def halloTuple := tuple: [Message, “wolf”, “hallo”];
// a template for message tuples from wolf.
def wolfTuples := tuple: [Message, “wolf”, var: `content];
// a template for any message tuples.
def msgTuples := tuple: [Message, var: `from, var: `content];

TOTAM provides operations to add and read tuples from the tuple space as follows:

// add tuple to tuple space
myTupleSpace.out(halloTuple);
// get a Message tuple
def aMessageTuple := myTupleSpace.rdp(msgTuples);
// get all Message tuples.
def messageTuples := myTupleSpace.rdg(msgTuples);

The rdp(template) and rdg(template) operations return a tuple or all tuples matching the template in the tuple space if present (without removing), respectively. Note that these operations are non-blocking. The out(tuple) operation to insert a private tuple in the tuple space. In order for applications to insert a public tuple, thereby making it available to other collocated TOTAM systems, the inject: operation is provided.

myTupleSpace.goOnline(); 
myTupleSpace.inject: halloTuple;

Note that the network facilities are disabled by default, so before injecting something in the network, the goOnline() method must be called on the tuple space.

A tuple injected to the network carries the following default propagation protocol.

def defaultPropagationProtocol(){
  isolate: {
    //receiver-side protocol
    def decideEnter(ts) { true };
    def doAction(ts){};
    def changeTupleContent(ts){self};
    def decideStore(ts) {true};
    //sender-side protocol
    def inScope(senderDescriptor,receiverDescriptor){ true };
    def decideDie(ts){false};
  };
};

However, other propagation protocols can be created and attached to a tuple before being injected in the network as follows:

//define a new propagation protocol
def blueProtocol := propagationProtocol: {
  def inScope(senderDescriptor,receiverDescriptor) { 
    receiverDescriptor.team == "blue" };
};
// attach the protocol to a tuple
def aBlueTuple := tuple: [Message, "hallo"] 
withPropagationProtocol: blueProtocol;
// inject the tuple to the network
def publication := inject: aBlueTuple;

The propagationProtocol: operation creates a propagation protocol object which extends the default propagation protocol object with other semantics. this sample code shows a protocol based on the operational sketch figure that checks whether the receiver of the tuple is part of the blue team. This is attached to the tuple by means of the tuple:withPropagationProtocol: operation which is then injected into the network. The inject: operation returns a publication object which can be used as follows to remove the tuple from the network.

// sends an antituple to notify the removal of this tuple.
publication.retract();

In order to notify the removal of a tuple, TOTAM sends an antituple for the removed tuple. For every tuple there is (conceptually) a unique antituple with the same format and content, but with a different sign. All tuples injected by an application have positive sign while their antituples have a negative sign. Whenever a tuple and its antituple are stored in the same tuple space, they immediately annihilate one another, i.e. they both get removed from the tuple space. By means of antituples, TOTAM can “unsend” tuples injected to the network.

Further Reading

TOTAM: Scoped Tuples for the Ambient, C. Scholliers, E. Gonzalez Boix, W. De Meuter. Proceedings of the Second International DisCoTec Workshop on Context-aware Adaptation Mechanisms for Pervasive and Ubiquitous Services (CAMPUS 2009), from Electronic Communications of the EASST, eds. 2009. ( pdf)

Note: The paper above and this webpage may have differ in the syntax for TOTAM. This webpage has been updated to fit the current implementation of TOTAM.

uf/totam.1334604062.txt.gz · Last modified: 2014/03/19 12:28 by jorge
 
 
 
Recent changes RSS feed Creative Commons License Donate Powered by PHP Valid XHTML 1.0 Valid CSS Driven by DokuWiki